كيفية إستخراج مفتاح التفعيل الخاص بنسخة ويندوز 7,8,10

نظام ويندوز

كتبه : عبد الرحمن محمد

1 أغسطس,2016

Product Key

في وقت ما ربما تريد إستخراج مفتاح التفعيل المُستخدم في نسخة الويندوز الخاصه بك او التي قمت بشراؤها ومثبته حالياً علي حاسوبك، ولكن لا تعرف كيف يمكن لك معرفة هذا المفتاح او الكود بعد كتابته اثناء تفعيل النسخة إلا من خلال صندوق الاسطوانة او الفلاشة الاصلية من مايكروسوفت، لكن إذا اردت معرفته من خلال نظام التشغيل نفسه فلا تستطيع فعل ذلك لان مايكروسوفت تقوم بتشفيره مباشرةً ويظهر لك الـ ID فقط، لكن الامر لم يكن مستحيل فهناك عدة طرق لمعرفة مفتاح التفعيل المُستخدم في نسخة الويندوز لديك سواء ويندوز 10 او 8 او 7، وفي هذا الموضوع سنقوم بإستعراض إحدي تلك الطرق لمعرفة سيريال النسخة بل وحفظ نسخة إحتياطية منه بضغطة زر.

Explore Product Key

كل ما عليك عزيزي القارئ هو ان تقوم بفتح اداة المفكرة Notepad في الويندوز عن طريق فتح قائمة إبدأ ثم تذهب إلي Windows Accessories وبه ستضغط علي Notepad وستفتح معك نافذة المفكرة او يُمكنك البحث عنها في حقل البحث في شريط المهام بويندوز 10. علي اي حال بعد فتح النافذة ستقوم بلصق الامر التالي بها:

Option Explicit
Dim objshell,path,DigitalID, Result
Set objshell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
DigitalID = objshell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'Get ProductName, ProductID, ProductKey
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)
ProductData = ProductName & vbNewLine & ProductID & vbNewLine & ProductKey
'Show messbox if save to a file
If vbYes = MsgBox(ProductData & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
Save ProductData
End If

'Convert binary to chars
Function ConvertToKey(Key)
Const KeyOffset = 52
Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
'Check if OS is Windows 8
isWin8 = (Key(66) \ 6) And 1
Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
i = 24
Maps = "BCDFGHJKMPQRTVWXY2346789"
Do
Current= 0
j = 14
Do
Current = Current* 256
Current = Key(j + KeyOffset) + Current
Key(j + KeyOffset) = (Current \ 24)
Current=Current Mod 24
j = j -1
Loop While j >= 0
i = i -1
KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
Last = Current
Loop While i >= 0

If (isWin8 = 1) Then
keypart1 = Mid(KeyOutput, 2, Last)
insert = "N"
KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
If Last = 0 Then KeyOutput = insert & KeyOutput
End If

ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)

End Function
'Save data to a file
Function Save(Data)
Dim fso, fName, txt,objshell,UserName
Set objshell = CreateObject("wscript.shell")
'Get current user name
UserName = objshell.ExpandEnvironmentStrings("%UserName%")
'Create a text file on desktop
fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
Set fso = CreateObject("Scripting.FileSystemObject")
Set txt = fso.CreateTextFile(fName)
txt.Writeline Data
txt.Close
End Function

وبعد نسخ ولصق هذه الاكواد في نافذة المفكرة Notepad، ستقوم بالضغط علي قسم File بالاعلي ثم تقوم بالضغط علي خيار Save as من القائمة المنسدلة.

save as notepad

لتظهر لك نافذة تتصفح منها مكان حفظ الملف، ولكن يجب مراعاه وضع اسم للملف وفي نهاية الاسم تقوم بإدخال “.vbs” حيث يجب كتابة هذا الاختصار لكي يتم حفظ الملف علي انه اسكربت، ثم تضغط علي زر Save بالاسفل، وبعدها سيتم إنشاء ملف صغير في المكان التي قمت فيه بحفظ الملف وبمجرد النقر عليه مزدوجاً سيتم عرض نافذة مصغرة بها مفتاح التفعيل وايضاً معرف الجهاز او الـ ID وهناك زر Yes بالاسفل يُمكنك النقر عليها ليتم حفظ نسخة إحتياطية من هذه البيانات، حيث بمجرد فعل ذلك حقاً سيتم إنشاء ملف text يحتوي علي البيانات.

أحدث الأخبار

المزيد

ماذا نعرف عن رقاقة GS101 القادمة في هاتف Google pixel 6 1

18 أبريل,2021

ماذا نعرف عن رقاقة GS101 القادمة في هاتف Google pixel 6

Samsung تكشف عن أقوى Galaxy يوم 28 أبريل الجاري 2

14 أبريل,2021

Samsung تكشف عن أقوى Galaxy يوم 28 أبريل الجاري

أحدث الهواتف

المزيد

مواصفات ومميزات وعيوب وسعر Samsung Galaxy A72 في مصر

18 أبريل,2021

مواصفات ومميزات وعيوب وسعر Samsung Galaxy A72 في مصر

سعر ومواصفات ومميزات وعيوب Mi Mix Fold القابل للطي

5 أبريل,2021

سعر ومواصفات ومميزات وعيوب Mi Mix Fold القابل للطي

التعليقات

  1. جزاكم الله خيراً م/عبد الرحمن، و لكن لي سؤال اذا تفضلتم و هو: هل يمكنني استخدام مفتاح تفعيل نسخة ويندوز 10 علي حاسوب اخر ،بعد استخدامه علي اللاب توب ( ااقصد مثلاً :اذا كنت اشتريت مفتاح التفعيل لحاسوب، ولسبب ما قمت ببيعه او تمت سرقة اللاب توب، واريد ان استخدم هذا المفتاح علي الحاسوب الجديد.
    ملحوظة :-المفتاح مرتبط ببريدي الألكتروني علي مايكرو سوفت.
    شكراً جزيلاً

    1. هو طالما الرخصة مش OEM -اي مش جاية مع الجهاز- ممكن تنقلها عادي وبترتبط بأكونت مايكروسوفت الخاص بك
      بمجرد ما اللابتوب القديم يتشال من عليه نسخة الويندوز المفعلة بالرخصة دي هتقدر تستعمل الرخصة على جهاز تاني بدون مشاكل
      تقدر برضه تشيل الأجهزة المرتبطة بحسابك من خلال اللينك
      https://support.microsoft.com/en-us/help/4558767/microsoft-account-manage-your-devices

اترك تعليقاً

لن يتم نشر عنوان بريدك الإلكتروني.